How do I combine variables into variable names?

[voodoogodman]

I am wondering how I can combine a variable(s) into a variable name?

Example script:

Code: Select all

Repeat>Card
  Let>Card=Card+1
  Repeat>Column
    Let>Column=Column+1
    Repeat>Row
      Let>Row=Row+1
      Let>Place_%Card%%Column%%Row%=1
    Until>Row,5
  Until>Column,5
Until>Card,3

I would like to have a bunch of variables named:
Place_111
Place_112
Place_113
Place_114
Place_115
Place_121
.
.
.
Place_355

All equal to 1 or whatever.

Help a noob.

[Marcus Tettmar]

Exactly as you have done but you will need to intialise the loop counters:

Code: Select all

Let>Card=0
Repeat>Card
  Let>Card=Card+1
  Let>Column=0
  Repeat>Column
    Let>Column=Column+1
    Let>Row=0
    Repeat>Row
      Let>Row=Row+1
      Let>Place_%Card%%Column%%Row%=1
    Until>Row,5
  Until>Column,5
Until>Card,3

[voodoogodman]

Thank you for your speedy reply.

If that looked good then I have another related issue concerning this same situation.

How could I get the value out and compare to another value.

Here's what I've got, but it doesn't work.
Or If I wanted to send> the value of Place_%CPCCard%%CPCColumn%%CPCRow% instead of comparing them.
It gives me an 'Unknown Identifier Place_111' Error
I tried %Place_%CPCCard%%CPCColumn%%CPCRow%% no good.
All the Place_*** variables have been initialized and given values in a previous subroutine. The watch list confirms this.

Code: Select all

Let>CPCCard=0
Let>CPCRow=0
Let>CPCColumn=0
Let>CallerBall=100
  Repeat>CallerBall
    Let>CallerBall=CallerBall+1
    Repeat>CPCCard
      Let>CPCCard=CPCCard+1
      Repeat>CPCColumn
        Let>CPCColumn=CPCColumn+1
        Repeat>CPCRow
          Let>CPCRow=CPCRow+1
          If>Place_%CPCCard%%CPCColumn%%CPCRow%=%CallerBall%
            Gosub>CheckForDaub
          endif
        Until>CPCRow,5
      Until>CPCColumn,5
    Until>CPCCard,3
  Until>Callerball,175

I'm trying to minimize how much of my code is made public. If you'd like me to send the complete code, I'd prefer to do it privately.

[Marcus Tettmar]

Like so:

Code: Select all

Let>CPCCard=0
Let>CPCRow=0
Let>CPCColumn=0
Let>CallerBall=100
  Repeat>CallerBall
    Let>CallerBall=CallerBall+1
    Repeat>CPCCard
      Let>CPCCard=CPCCard+1
      Repeat>CPCColumn
        Let>CPCColumn=CPCColumn+1
        Repeat>CPCRow
          Let>CPCRow=CPCRow+1
          Let>tmp_card=Place_%CPCCard%%CPCColumn%%CPCRow%
          If>tmp_card=%CallerBall%
            Gosub>CheckForDaub
          endif
        Until>CPCRow,5
      Until>CPCColumn,5
    Until>CPCCard,3
  Until>Callerball,175

(use Let to set a basic variable to the value of the array variable first, then use that in your If).

[voodoogodman]

You're awesome. Thank you so much.