net send

[Kimble]

Im trying to make heads or tails of this. I want to make a macro to use the command prompt box to send a "netsend" message across a network. I have recorded the macro but it doesnt work at all. Would any one be kind enough to write it for me so that I could look at the script and see what is happening please?

Many thanks

[support]

All you need is:

Run>Net Send ComputerName Message

Or:

Run>cmd.exe /c Net Send ComputerName Message

[CyberCitizen]

This Is One That I Use At Work. Note We Do Not Work Off IP Address We Have Allocated C-Numbers To Everyone (Login Username) So That We Sent To That.

Note I Know This Is An Old Topic, However Thought I Could Help New Users.


Let>APP_TITLE=NetSend Utility

Dialog>NetSend_History
Caption=NetSend History
Top=0
Width=809
Left=0
Height=410
Memo=History,8,8,785,329,%File_History%
Button=Exit,360,344,75,25,1
EndDialog>NetSend_History

Dialog>NetSend
Caption=NetSend
Top=0
Width=317
Left=0
Height=266
Label=Enter User's C Number (e.g c957449),8,8
Label=Message,8,48
Label=From,8,160
Label=© 2005%CRLF%Michael Allen,16,200
Edit=address,16,24,281,
Memo=message,16,64,281,89,
Edit=from,16,176,281,
Button=Send,104,200,43,25,1
Button=History,152,200,51,25,3
Button=Fix,208,200,43,25,4
Button=Close,256,200,43,25,2
EndDialog>NetSend

Label>Start
Show>NetSend,r

If>r=2,End
If>r=3,History
If>r=4,Fix
If>%NetSend.address%=*,domain
If>%NetSend.address%=/domain,domain
If>r=1,Send

Label>domain
Dialog>Domain_Sending
Caption=Domain Sending Not Allowed
Top=100
Width=328
Left=100
Height=177
Memo=domain_message,8,8,305,97,Net send is used to send messages to any host on network (LAN or the Internet) where messenger service is running. This will send a message to a particular user and a pop-up dialog box will appear on their screen. %CRLF%%CRLF%Please be advised that domain sending is not allowed.
Button=Exit Program,8,112,305,25,3
EndDialog>Domain_Sending

Show>Domain_Sending,x
If>x=3,End
Goto>End

Label>Fix
Let>RP_WAIT=1
Let>RP_WINDOWMODE=2
Run Program>net name /delete %USER_NAME%
Run Program>net name /add %USER_NAME%
Let>RP_WINDOWMODE=1
Let>RP_WAIT=0
Let>MSG_WIDTH=325
Let>MSG_HEIGHT=140
MessageModal>%USER_NAME% Has Been Added To The Net Send Name List.%CRLF%You Should Now Be Able To Receive NetSend Messages.
Goto>End

Label>History
Let>File_History=1
ReadFile>c:\NetSend.txt,File_History

Show>NetSend_History,File_History_Exit
ResetDialogAction>NetSend
CloseDialog>NetSend
Goto>End

Label>Send
Let>RP_WAIT=1
Let>RP_WINDOWMODE=2
Run Program>net send %NetSend.address% "%NetSend.message%%CRLF%--%CRLF%From: %NetSend.from% - %USER_NAME%"
Wait>1
Run Program>net send %USER_NAME% "Your Message Has Been Sent To %NetSend.address%"
Let>RP_WINDOWMODE=1
Let>RP_WAIT=0
ResetDialogAction>NetSend
CloseDialog>NetSend
//This Part Of The Script Will Call The Date, Time, & Message Sent
GetDate>date
Min>Minutes
Hour>Hour
WriteLn>C:\NetSend.txt,result,==============================%CRLF%Message Sent: %date% %Hour%:%Minutes%%CRLF%%CRLF%To: %NetSend.address%%CRLF%%CRLF%%NetSend.message%%CRLF%%CRLF%From: %NetSend.from% - %USER_NAME%
Goto>Start

Label>End