MidStr equivalent

[timle]

Is there a function equivalent with MidStr but instead of "string,start,length,result", it would be "string,END,length,result" ? I want to display the file name without the .extention but the file name is not consistent and the extention is

thank you

[Marcus Tettmar]

Anything wrong with:

Let>filename=c:\dir\somefile.ext
Position>.,filename,1,pdot
Let>pdot=pdot-1
MidStr>filename,1,pdot,filename
MessageModal>filename

[jpuziano]

There's a problem...

A period (.) is a valid character for a filename so if we ran across a file called: c:\dir\some.file.ext

that script would return the erroneous value: c:\dir\some

The script below properly searches for the first period "on the right" and would return: c:\dir\some.file

which I think is what is desired:

Code: Select all

Let>filename=c:\dir\some.file.ext
Length>filename,filename_length
Let>char_position=filename_length

Label>look_for_right_most_period
MidStr>filename,char_position,1,this_char
If>this_char=.,found_right_most_period
Sub>char_position,1
If>char_position=0,no_periods_in_filename
Goto>look_for_right_most_period

Label>found_right_most_period
Sub>char_position,1
MidStr>filename,1,char_position,filename
MDL>filename
Goto>end

Label>no_periods_in_filename
MDL>Sorry, no period (.) in filename: %filename%

Label>end

[JRL]

I agree, extra dots in file names can be hazardous. I've also been bitten by dots in directory names.

I like using separate to remove file extensions.

Code: Select all

Let>filename=c:\dir\some.directory\some.file.ext
Separate>%filename%,\,dir
Let>value=dir_%dir_count%
Separate>%value%,.,ext
If>%ext_count%=1
  Let>filename= There is no extension in file%CRLF%%filename%
  Goto>NoDot
EndIf
Let>value=ext_%ext_count%
Position>.%value%,filename,1,ext
sub>ext,1
MidStr>filename,1,%ext%,filename
Label>NoDot
MessageModal>filename

[joe88888]

Try this, maybe ok?

Let>filename=c:\dir\somefile.ext
Length>%filename%,Len
let>len=len-4
//4=.ext
MidStr>filename,1,len,filename
MessageModal>filename

[Bob Hansen]

Hello joe88888

I think that will only work with files that have 3 char extensions.
What about *.html files?

[Marcus Tettmar]

VBScript has a very handy function called InStrRev which works like InStr but in reverse. So it finds the position of a character/substring in a string starting from the end. So we can use it to solve this problem as follows:

Code: Select all

VBSTART
VBEND

Let>filename=c:\some.file.name.ext
VBEval>InStrRev("%filename%",".")-1,rpos
MidStr>filename,1,rpos,filename
MessageModal>filename

If you don't want to use VBScript here's another solution using the Separate command. This splits the string up between the dots and then puts them back together again omitting the last part:

Code: Select all

Let>filename=some.file.name.ext
Separate>filename,.,parts
Let>filename=parts_1
Let>k=1
Repeat>k
  Let>k=k+1
  Let>this=parts_%k%
  Let>filename=%filename%.%this%
Until>k={%parts_count%-1}
MessageModal>filename

[jpuziano]

Thanks JRL and Marcus for the improved code examples. There are still two cases which produce odd results:

Let>filename=c:\some.file.name.ext\
JRL code produces: -blank-
Marcus code (both) produces: c:\some.file.name
Actually there is no filename here, just a directory so what should we display?

Let>filename=c:\some.file.name.ext\.
JRL code produces: c:\some
Marcus code (both) produces: c:\some.file.name.ext\
This one may not be fair as it may not be possible to name a file just .

Try to rename a file with the following command:
RenameFile>c:\junk.txt,c:\.

It does not rename it to just .
Maybe Marcus can tell us why; I think it has special meaning and may mean "this directory".

One last thing...

Separate>list,delimiter,returnvar

Stepping through JRL's code with the debugger in the first example, its interesting to see what happens when the Separate> command is fed . as both list and delimiter. Its just a single character, a period, why does it generate two list elements?

[Marcus Tettmar]

Let>filename=c:\some.file.name.ext\
JRL code produces: -blank-
Marcus code (both) produces: c:\some.file.name
Actually there is no filename here, just a directory so what should we display?

Well, you supplied a directory. The code was written assuming a filename was supplied. If necessary modify the code to first check to see if the supplied argument is a directory or a filename.

This one may not be fair as it may not be possible to name a file just .

Try to rename a file with the following command:
RenameFile>c:\junk.txt,c:\.

It does not rename it to just .
Maybe Marcus can tell us why; I think it has special meaning and may mean "this directory".

Correct.

Stepping through JRL's code with the debugger in the first example, its interesting to see what happens when the Separate> command is fed . as both list and delimiter. Its just a single character, a period, why does it generate two list elements?

It returns two elements containing nothing because "." as a list with delimiter "." is a list of two lots of nothing.

[Me_again]

Hello joe88888

I think that will only work with files that have 3 char extensions.
What about *.html files?

The original question to which that code was part of the answer stated that it was a .pdf file.

[joe88888]

but the file name is not consistent and the extention is

In the original it states the extention is consistent, if html file then change 4 to 5